viewcvs.cgi/types/patterns.ml

exception Error of string
open Ident

(* Syntactic algebra *)
(* Constraint: any node except Constr has fv<>[] ... *)
type d =
  | Constr of Types.descr
  | Cup of descr * descr
  | Cap of descr * descr
  | Times of node * node
  | Xml of node * node
  | Record of label * node
  | Capture of id
  | Constant of id * Types.const
and node = {
  id : int;
  mutable descr : descr option;
  accept : Types.node;
  fv : fv
} and descr = Types.descr * fv * d

let id x = x.id
let descr x = match x.descr with Some d -> d | None -> failwith "Patterns.descr"
let fv x = x.fv
let accept x = Types.internalize x.accept

let printed = ref []
let to_print = ref []
let rec print ppf (a,_,d) = 
(*  Format.fprintf ppf "[%a]" Types.Print.print_descr a; *)
  match d with
    | Constr t -> Types.Print.print_descr ppf t
    | Cup (p1,p2) -> Format.fprintf ppf "(%a | %a)" print p1 print p2
    | Cap (p1,p2) -> Format.fprintf ppf "(%a & %a)" print p1 print p2
    | Times (n1,n2) -> 
        Format.fprintf ppf "(P%i,P%i)" n1.id n2.id;
        to_print := n1 :: n2 :: !to_print
    | Xml (n1,n2) -> 
        Format.fprintf ppf "XML(P%i,P%i)" n1.id n2.id;
        to_print := n1 :: n2 :: !to_print
    | Record (l,n) -> 
        Format.fprintf ppf "{ %s =  P%i }" (LabelPool.value l) n.id;
        to_print := n :: !to_print
    | Capture x ->
        Format.fprintf ppf "%s" (Id.value x)
    | Constant (x,c) ->
        Format.fprintf ppf "(%s := %a)" (Id.value x) 
          Types.Print.print_const c

let dump_print ppf =
  while !to_print <> [] do
    let p = List.hd !to_print in
    to_print := List.tl !to_print;
    if not (List.mem p.id !printed) then
      ( printed := p.id :: !printed;
        Format.fprintf ppf "P%i:=%a\n" p.id print (descr p)
      )
  done

let print ppf d =
  Format.fprintf ppf "%a@\n" print d;
  dump_print ppf


let counter = State.ref "Patterns.counter" 0

let make fv =
  incr counter;
  { id = !counter; descr = None; accept = Types.make (); fv = fv }

let define x ((accept,fv,_) as d) =
  assert (x.fv = fv);
  Types.define x.accept accept;
  x.descr <- Some d

let constr x = (x,IdSet.empty,Constr x)
let cup ((acc1,fv1,_) as x1) ((acc2,fv2,_) as x2) = 
  if not (IdSet.equal fv1 fv2) then (
    let x = match IdSet.pick (IdSet.diff fv1 fv2) with
      | Some x -> x
      | None -> match IdSet.pick (IdSet.diff fv2 fv1) with Some x -> x 
          | None -> assert false
    in
    raise 
      (Error 
         ("The capture variable " ^ (Id.value x) ^ 
          " should appear on both side of this | pattern"))
  );
  (Types.cup acc1 acc2, IdSet.cup fv1 fv2, Cup (x1,x2))
let cap ((acc1,fv1,_) as x1) ((acc2,fv2,_) as x2) = 
  if not (IdSet.disjoint fv1 fv2) then (
    match IdSet.pick (IdSet.cap fv1 fv2) with
      | Some x -> 
          raise 
          (Error 
             ("The capture variable " ^ (Id.value x) ^ 
              " cannot appear on both side of this & pattern"))
      | None -> assert false
  );
  (Types.cap acc1 acc2, IdSet.cup fv1 fv2, Cap (x1,x2))
let times x y =
  (Types.times x.accept y.accept, IdSet.cup x.fv y.fv, Times (x,y))
let xml x y =
  (Types.xml x.accept y.accept, IdSet.cup x.fv y.fv, Xml (x,y))
let record l x = 
  (Types.record l x.accept, x.fv, Record (l,x))
let capture x = (Types.any, IdSet.singleton x, Capture x)
let constant x c = (Types.any, IdSet.singleton x, Constant (x,c))


(* Static semantics *)

let cup_res v1 v2 = Types.Positive.cup [v1;v2]
let empty_res fv = IdMap.constant (Types.Positive.ty Types.empty) fv
let times_res v1 v2 = Types.Positive.times v1 v2

module MemoFilter = Map.Make 
  (struct type t = Types.descr * node let compare = compare end)

let memo_filter = ref MemoFilter.empty

let rec filter_descr t (_,fv,d) : Types.Positive.v id_map =
(* TODO: avoid is_empty t when t is not changing (Cap) *)
  if Types.is_empty t 
  then empty_res fv
  else
    match d with
      | Constr _ -> IdMap.empty
      | Cup ((a,_,_) as d1,d2) ->
          IdMap.merge cup_res
            (filter_descr (Types.cap t a) d1)
            (filter_descr (Types.diff t a) d2)
      | Cap (d1,d2) ->
          IdMap.merge cup_res (filter_descr t d1) (filter_descr t d2)
      | Times (p1,p2) -> filter_prod fv p1 p2 t
      | Xml (p1,p2) -> filter_prod ~kind:`XML fv p1 p2 t
      | Record (l,p) ->
          filter_node (Types.Record.project t l) p
      | Capture c ->
          IdMap.singleton c (Types.Positive.ty t)
      | Constant (c, cst) ->
          IdMap.singleton c (Types.Positive.ty (Types.constant cst))

and filter_prod ?kind fv p1 p2 t =
  List.fold_left 
    (fun accu (d1,d2) ->
       let term = 
         IdMap.merge times_res (filter_node d1 p1) (filter_node d2 p2)
       in
       IdMap.merge cup_res accu term
    )
    (empty_res fv)
    (Types.Product.normal ?kind t)


and filter_node t p : Types.Positive.v id_map =
  try MemoFilter.find (t,p) !memo_filter
  with Not_found ->
    let (_,fv,_) as d = descr p in
    let res = IdMap.map_from_slist (fun _ -> Types.Positive.forward ()) fv in
    memo_filter := MemoFilter.add (t,p) res !memo_filter;
    let r = filter_descr t (descr p) in
    IdMap.collide Types.Positive.define res r;
    r

let filter t p =
  let r = filter_node t p in
  memo_filter :=  MemoFilter.empty;
  IdMap.get (IdMap.map Types.Positive.solve r)


(* Normal forms for patterns and compilation *)

let min (a:int) (b:int) = if a < b then a else b

module Normal : sig 
  type 'a sl = 'a SortedList.t
  type ('a,'b) sm = ('a,'b) SortedMap.t

  type source = 
    | SCatch | SConst of Types.const 
    | SLeft | SRight | SRecompose 
  type result = source id_map

  type nnf = node sl * Types.descr
  type 'a nline = (result *  'a) list
  type record =
    | RecNolabel of result option * result option
    | RecLabel of label * (nnf * nnf) nline 
  type t = {
    nfv    : fv;
    ncatchv: fv;
    na     : Types.descr;
    nbasic : Types.descr nline;
    nprod  : (nnf * nnf) nline;
    nxml   : (nnf * nnf) nline;
    nrecord: record;
  }

  val any_basic: Types.descr
  val first_label: descr -> label
  val normal: label option -> Types.descr -> node list -> t
end = 
struct
  let any_basic = 
    Types.Record.or_absent
      (Types.neg (List.fold_left Types.cup Types.empty
                    [Types.Product.any_xml;
                     Types.Product.any;
                     Types.Record.any]))


  type 'a sl = 'a SortedList.t
  type ('a,'b) sm = ('a,'b) SortedMap.t

  type source = 
    | SCatch | SConst of Types.const 
    | SLeft | SRight | SRecompose 
  type result = source id_map

  type nnf = node sl * Types.descr   (* pl,t;   t <= \accept{pl} *)
  type 'a nline = (result *  'a) sl
  type record =
    | RecNolabel of result option * result option
    | RecLabel of label * (nnf * nnf) nline
  type t = {
    nfv    : fv;
    ncatchv: fv;
    na     : Types.descr;
    nbasic : Types.descr nline;
    nprod  : (nnf * nnf) nline;
    nxml   : (nnf * nnf) nline;
    nrecord: record
  }


  let fus = IdMap.union_disj
  let slcup = SortedList.cup

  let nempty lab = 
    { nfv = IdSet.empty; ncatchv = IdSet.empty; 
      na = Types.empty;
      nbasic = []; nprod = []; nxml = []; 
      nrecord = (match lab with 
                   | Some l -> RecLabel (l,[]) 
                   | None -> RecNolabel (None,None))
    }


  let ncup nf1 nf2 = 
    (* assert (Types.is_empty (Types.cap nf1.na nf2.na)); *)
    (* assert (nf1.nfv = nf2.nfv); *)
    { nfv = nf1.nfv;
      ncatchv = IdSet.cap nf1.ncatchv nf2.ncatchv;
      na      = Types.cup nf1.na nf2.na;
      nbasic  = SortedList.cup nf1.nbasic nf2.nbasic;
      nprod   = SortedList.cup nf1.nprod nf2.nprod;
      nxml    = SortedList.cup nf1.nxml nf2.nxml;
      nrecord = (match (nf1.nrecord,nf2.nrecord) with
                   | RecLabel (l1,r1), RecLabel (l2,r2) -> 
                       assert (l1 = l2); RecLabel (l1, slcup r1 r2)
                   | RecNolabel (x1,y1), RecNolabel (x2,y2) -> 
                       RecNolabel((if x1 = None then x2 else x1),
                                (if y1 = None then y2 else y1))
                   | _ -> assert false)
    }

  let double_fold f l1 l2 =
    SortedList.from_list
      (List.fold_left 
         (fun accu x1 ->
            List.fold_left
            (fun accu x2 ->
               f accu x1 x2
            )
            accu l2
         ) [] l1)
         
  let ncap nf1 nf2 =
    let prod accu (res1,((pl1,t1),(ql1,s1))) (res2,((pl2,t2),(ql2,s2))) =
      let t = Types.cap t1 t2 in
      if Types.is_empty t then accu else
        let s = Types.cap s1 s2  in
        if Types.is_empty s then accu else
          (fus res1 res2, ((slcup pl1 pl2,t),(slcup ql1 ql2,s))) :: accu
    in
    let basic accu (res1,t1) (res2,t2) =
      let t = Types.cap t1 t2 in
      if Types.is_empty t then accu else
        (fus res1 res2, t) :: accu
    in
    let do_record r1 r2 = match r1,r2 with
      | RecLabel (l1,r1), RecLabel (l2,r2) ->
          assert (l1 = l2);
          RecLabel(l1, double_fold prod r1 r2)
      | RecNolabel (x1,y1), RecNolabel (x2,y2) ->
          let x = match x1,x2 with 
            | Some res1, Some res2 -> Some (fus res1 res2) 
            | _ -> None
          and y = match y1,y2 with
            | Some res1, Some res2 -> Some (fus res1 res2)
            | _ -> None in
          RecNolabel (x,y)
      | _ -> assert false
    in
    { nfv = IdSet.cup nf1.nfv nf2.nfv;
      ncatchv = IdSet.cup nf1.ncatchv nf2.ncatchv;
      na = Types.cap nf1.na nf2.na;
      nbasic = double_fold basic nf1.nbasic nf2.nbasic;
      nprod = double_fold prod nf1.nprod nf2.nprod;
      nxml = double_fold prod nf1.nxml nf2.nxml;
      nrecord = do_record nf1.nrecord nf2.nrecord;
    }

  let nnode p = [p], Types.descr p.accept
  let empty_res = IdMap.empty

  let ntimes lab acc p q = 
    let src_p = IdMap.constant SLeft p.fv
    and src_q = IdMap.constant SRight q.fv in
    let src = IdMap.merge_elem SRecompose src_p src_q in 
    { nempty lab with 
        nfv = IdSet.cup p.fv q.fv; 
        na = acc;
        nprod = [ (src, (nnode p, nnode q)) ];
    }

  let nxml lab acc p q = 
    let src_p = IdMap.constant SLeft p.fv
    and src_q = IdMap.constant SRight q.fv in
    let src = IdMap.merge_elem SRecompose src_p src_q in 
    { nempty lab with 
        nfv = IdSet.cup p.fv q.fv; 
        na = acc;
        nxml =  [ (src, (nnode p, nnode q)) ];
    }
    
  let nrecord lab acc l p =
    match lab with
      | None -> assert false
      | Some label ->
(*        Printf.eprintf "[ l = %s; label = %s ]\n" 
            (LabelPool.value l)
            (LabelPool.value label); *)
          assert (label <= l);
          if l == label then
            let src = IdMap.constant SLeft p.fv in
            { nempty lab with
                nfv = p.fv;
                na = acc;
                nrecord = RecLabel(label, 
                                 [ (src,(nnode p, ([], Types.any))) ])}
          else
            let src = IdMap.constant SRight p.fv in
            let p' = make p.fv in  (* optimize this ... *)
              (* cache the results to avoid looping ... *)
            define p' (record l p);
            { nempty lab with
                nfv = p.fv;
                na = acc;
                nrecord = RecLabel(label,
                                 [ (src,(([], Types.Record.any_or_absent), 
                                         nnode p')) ])}
          

  let nconstr lab t =
    let aux = List.map (fun (t1,t2) -> empty_res, (([],t1),([],t2))) in
    let record = 
      match lab with
        | None ->
            let (x,y) = Types.Record.empty_cases t in
            RecNolabel ((if x then Some empty_res else None), 
                      (if y then Some empty_res else None))
        | Some l ->
            RecLabel (l,aux (Types.Record.split_normal t l))
    in        
    { nempty lab with
        na = t;
        nbasic = [ empty_res, Types.cap t any_basic ];
        nprod = aux (Types.Product.normal t);
        nxml  = aux (Types.Product.normal ~kind:`XML t);
        nrecord = record
    }

  let nconstant lab x c = 
    let l = IdMap.singleton x (SConst c) in
    { nfv = IdSet.singleton x;
      ncatchv = IdSet.empty;
      na = Types.any;
      nbasic = [ (l,any_basic) ]; 
      nprod  = [ (l,(([], Types.any),([], Types.any))) ];
      nxml   = [ (l,(([], Types.any),([], Types.any))) ];
      nrecord = match lab with
        | None -> RecNolabel (Some l, Some l)
        | Some lab -> 
            RecLabel (lab, [ (l,(([], Types.Record.any_or_absent),
                               ([], Types.any))) ])
    }

  let ncapture lab x = 
    let l = IdMap.singleton x SCatch in
    { nfv = IdSet.singleton x;
      ncatchv = IdSet.singleton x;
      na = Types.any;
      nbasic = [ (l,any_basic) ]; 
      nprod  = [ (l,(([], Types.any),([], Types.any))) ];
      nxml   = [ (l,(([], Types.any),([], Types.any))) ];
      nrecord = match lab with
        | None -> RecNolabel (Some l, Some l)
        | Some lab -> 
            RecLabel (lab, [ (l,(([], Types.Record.any_or_absent),([], Types.any))) ])
    }

  let rec nnormal lab (acc,fv,d) =
    if Types.is_empty acc 
    then nempty lab
    else match d with
      | Constr t -> nconstr lab t
      | Cap (p,q) -> ncap (nnormal lab p) (nnormal lab q)
      | Cup ((acc1,_,_) as p,q) -> 
          ncup (nnormal lab p) (ncap (nnormal lab q) 
                                  (nconstr lab (Types.neg acc1)))
      | Times (p,q) -> ntimes lab acc p q
      | Xml (p,q) -> nxml lab acc p q
      | Capture x -> ncapture lab x
      | Constant (x,c) -> nconstant lab x c
      | Record (l,p) -> nrecord lab acc l p

(*TODO: when an operand of Cap has its first_label > lab,
  directly shift it*)

  let rec first_label (acc,fv,d) =
    if Types.is_empty acc 
    then LabelPool.dummy_max
    else match d with
      | Constr t -> Types.Record.first_label t
      | Cap (p,q) -> min (first_label p) (first_label q)
      | Cup ((acc1,_,_) as p,q) -> min (first_label p) (first_label q)
            (* should "first_label_type acc1" ? *)
      | Record (l,p) -> l
      | _ -> LabelPool.dummy_max

   
  let remove_catchv n =
    let ncv = n.ncatchv in
    let nlines l = 
      let l = List.map (fun (res,x) -> (IdMap.diff res ncv,x)) l in
(*       let l = SortedList.from_list l in (* Can get rid of it ? *) *)
      l in
    { nfv     = IdSet.diff n.nfv ncv;
      ncatchv = n.ncatchv;
      na      = n.na;
      nbasic  = nlines n.nbasic;
      nprod   = nlines n.nprod;
      nxml    = nlines n.nxml;
      nrecord = (match n.nrecord with
                   | RecNolabel (x,y) ->
                       let x = match x with 
                         | Some res -> Some (IdMap.diff res ncv) 
                         | None -> None in
                       let y = match y with 
                         | Some res -> Some (IdMap.diff res ncv) 
                         | None -> None in
                       RecNolabel (x,y)
                   | RecLabel (lab,l) -> RecLabel (lab, nlines l))
    }

  let normal l t pl =
    remove_catchv
      (List.fold_left 
         (fun a p -> ncap a (nnormal l (descr p))) 
         (nconstr l t) 
         pl)
end


module Compile = 
struct
  type actions =
    | AIgnore of result
    | AKind of actions_kind
  and actions_kind = {
    basic: (Types.descr * result) list;
    atoms: result Atoms.map;
    chars: result Chars.map;
    prod: result dispatch dispatch;
    xml: result dispatch dispatch;
    record: record option;
  }
  and record = 
    | RecLabel of label * result dispatch dispatch
    | RecNolabel of result option * result option
      
  and 'a dispatch =
    | Dispatch of dispatcher * 'a array
    | TailCall of dispatcher
    | Ignore of 'a
    | Impossible

  and result = int * source array
  and source = 
    | Catch | Const of Types.const 
    | Left of int | Right of int | Recompose of int * int
      
  and return_code = 
      Types.descr * int *   (* accepted type, arity *)
      (int * int id_map) list

  and interface =
    [ `Result of int
    | `Switch of interface * interface
    | `None ]

  and dispatcher = {
    id : int;
    t  : Types.descr;
    pl : Normal.t array;
    label : label option;
    interface : interface;
    codes : return_code array;
    mutable actions : actions option;
    mutable printed : bool
  }

  let array_for_all f a =
    let rec aux f a i =
      if i = Array.length a then true
      else f a.(i) && (aux f a (succ i))
    in
    aux f a 0

  let array_for_all_i f a =
    let rec aux f a i =
      if i = Array.length a then true
      else f i a.(i) && (aux f a (succ i))
    in
    aux f a 0

  let combine_kind basic prod xml record =
    try (
      let rs = [] in
      let rs = match basic with
        | [_,r] -> r :: rs
        | [] -> rs
        | _ -> raise Exit in
      let rs = match prod with
        | Impossible -> rs
        | Ignore (Ignore r) -> r :: rs
        | _ -> raise Exit in
      let rs = match xml with
        | Impossible -> rs
        | Ignore (Ignore r) -> r :: rs
        | _ -> raise Exit in
      let rs = match record with
        | None -> rs
        | Some (RecLabel (_,Ignore (Ignore r))) -> r :: rs
        | Some (RecNolabel (Some r1, Some r2)) -> r1 :: r2 :: rs
        | _ -> raise Exit in
      match rs with
        | ((_, ret) as r) :: rs when 
            List.for_all ( (=) r ) rs 
            && array_for_all 
              (function Catch | Const _ -> true | _ -> false) ret
            -> AIgnore r
        | _ -> raise Exit
    )
    with Exit -> 
      AKind 
      { basic = basic;
        atoms = 
           Atoms.mk_map (List.map (fun (t,r) -> Types.Atom.get t, r) basic);
        chars = 
           Chars.mk_map (List.map (fun (t,r) -> Types.Char.get t, r) basic);
        prod = prod; 
        xml = xml; 
        record = record }
      
  let combine (disp,act) =
    if Array.length act = 0 then Impossible
    else
      if (array_for_all (fun (_,ar,_) -> ar = 0) disp.codes) 
         && (array_for_all ( (=) act.(0) ) act) then
           Ignore act.(0)
      else
        Dispatch (disp, act)


  let detect_right_tail_call = function
    | Dispatch (disp,branches) 
        when
          array_for_all_i
            (fun i (code,ret) ->
               (i = code) && 
               (array_for_all_i 
                  (fun pos -> 
                     function Right j when pos = j -> true | _ -> false)
                  ret
               )
            ) branches
          -> TailCall disp
    | x -> x

  let detect_left_tail_call = function
    | Dispatch (disp,branches)
        when
          array_for_all_i
            (fun i -> 
               function 
                 | Ignore (code,ret) ->
                     (i = code) &&
                     (array_for_all_i 
                        (fun pos -> 
                           function Left j when pos = j -> true | _ -> false)
                        ret
               )
                 | _ -> false
            ) branches
          ->
         TailCall disp
    | x -> x
   
  let cur_id = State.ref "Patterns.cur_id" 0
                 (* TODO: save dispatchers ? *)
                 
  module DispMap = Map.Make(
    struct
      type t = Types.descr * Normal.t array
      let compare = compare
    end
  )
    
  let dispatchers = ref DispMap.empty
                      
  let dispatcher t pl lab : dispatcher =
    try DispMap.find (t,pl) !dispatchers
    with Not_found ->
      let nb = ref 0 in
      let codes = ref [] in
      let rec aux t arity i accu = 
        if Types.is_empty t then `None
        else
          if i = Array.length pl 
          then (incr nb; codes := (t,arity,accu)::!codes; `Result (!nb - 1))
          else
            let p = pl.(i) in
            let tp = p.Normal.na in
            assert(IdSet.disjoint p.Normal.nfv p.Normal.ncatchv);
            let v = p.Normal.nfv in
(*          let v = IdSet.diff p.Normal.nfv p.Normal.ncatchv in*)

(*          let tp = Types.normalize tp in *)
            let accu' = (i,IdMap.num arity v) :: accu in
            `Switch 
              (
               aux (Types.cap t tp) (arity + (IdSet.length v)) (i+1) accu',
               aux (Types.diff t tp) arity (i+1) accu
              )
      in
      let iface = aux t 0 0 [] in
      let res = { id = !cur_id; 
                  t = t;
                  label = lab;
                  pl = pl;
                  interface = iface;
                  codes = Array.of_list (List.rev !codes);
                  actions = None; printed = false } in
      incr cur_id;
      dispatchers := DispMap.add (t,pl) res !dispatchers;
      res
    
  let find_code d a =
    let rec aux i = function
      | `Result code -> code
      | `None -> assert false
      | `Switch (yes,_) when a.(i) <> None -> aux (i + 1) yes
      | `Switch (_,no) -> aux (i + 1) no
    in
    aux 0 d.interface

  let create_result pl =
    let aux x accu = match x with Some b -> b @ accu | None -> accu in
    Array.of_list (Array.fold_right aux pl [])

  let return disp pl f =
    let aux = function [x] -> Some (f x) | [] -> None | _ -> assert false in
    let final = Array.map aux pl in
    (find_code disp final, create_result final)
    
  let conv_source_basic s = match s with
    | Normal.SCatch -> Catch
    | Normal.SConst c -> Const c
    | _ -> assert false

  let assoc v l =
    try IdMap.assoc v l with Not_found -> -1

  let conv_source_prod left right v s = match s with
    | Normal.SCatch -> Catch
    | Normal.SConst c -> Const c
    | Normal.SLeft -> Left (assoc v left)
    | Normal.SRight -> Right (assoc v right)
    | Normal.SRecompose -> Recompose (assoc v left, assoc v right)

  let dispatch_basic disp : (Types.descr * result) list =
(* TODO: try other algo, using disp.codes .... *)
    let pl = Array.map (fun p -> p.Normal.nbasic) disp.pl in
    let tests =
      let accu = ref [] in
      let aux i (res,x) = accu := (x, [i,res]) :: !accu in
      Array.iteri (fun i -> List.iter (aux i)) pl;
      SortedMap.from_list SortedList.cup !accu in

    let t = Types.cap Normal.any_basic disp.t in
    let accu = ref [] in
    let rec aux (success : (int * Normal.result) list) t l = 
      if Types.non_empty t 
      then match l with
        | [] ->
            let selected = Array.create (Array.length pl) [] in
            let add (i,res) = selected.(i) <- res :: selected.(i) in
            List.iter add success;
            
            let aux_final res = IdMap.map_to_list conv_source_basic res in
            accu := (t, return disp selected aux_final) :: !accu
        | (ty,i) :: rem -> 
            aux (i @ success) (Types.cap t ty) rem; 
            aux success (Types.diff t ty) rem
    in
    aux [] t tests;
    !accu


  let get_tests pl f t d post =
    let accu = ref [] in
    let unselect = Array.create (Array.length pl) [] in
    let aux i x = 
      let yes, no = f x in
      List.iter (fun ( (pl,ty), info) -> accu := (ty,pl,i,info) :: !accu
                ) yes;
      unselect.(i) <- no @ unselect.(i) in
    Array.iteri (fun i -> List.iter (aux i)) pl;

    let lab =
      List.fold_left 
        (fun l (ty,pl,_,_) ->
           List.fold_left
             (fun l p -> min l (Normal.first_label (descr p)))
             (min l (Types.Record.first_label ty))
             pl
        ) LabelPool.dummy_max !accu in
    let lab = if lab= LabelPool.dummy_max then None else Some lab in

    let accu = 
      List.map (fun (ty,pl,i,info) -> 
                  let p = Normal.normal lab ty pl in
                  (p,[i, p.Normal.ncatchv, info])) 
        !accu in
    let sorted = Array.of_list (SortedMap.from_list SortedList.cup accu) in
    let infos = Array.map snd sorted in
    let disp = dispatcher t (Array.map fst sorted) lab in
    let result (t,_,m) =
      let selected = Array.create (Array.length pl) [] in
      let add r (i, ncv, inf) = selected.(i) <- (r,ncv,inf) :: selected.(i) in
      List.iter (fun (j,r) -> List.iter (add r) infos.(j)) m;
      d t selected unselect
    in
    let res = Array.map result disp.codes in
    post (disp,res)


  let make_branches t brs =
    let (_,brs) = 
      List.fold_left
        (fun (t,brs) (p,e) ->
           let p' = ([p],t) in
           let t' = Types.diff t (Types.descr (accept p)) in
           (t', (p',e) :: brs)
        ) (t,[]) brs in
        
    let pl = Array.map (fun x -> [x]) (Array.of_list brs) in
    get_tests 
      pl 
      (fun x -> [x],[])
      t
      (fun _ pl _ ->
         let r = ref None in
         let aux = function 
           | [(res,catchv,e)] -> assert (!r = None); 
               let catchv = IdMap.constant (-1) catchv in
               r := Some (IdMap.union_disj catchv res,e)
           | [] -> () | _ -> assert false in
         Array.iter aux pl;
         let r = match !r with None -> assert false | Some x -> x in
         r
      )
      (fun x -> x)


  let rec dispatch_prod ?(kind=`Normal) disp =
    let pl = 
      match kind with
        | `Normal ->  Array.map (fun p -> p.Normal.nprod) disp.pl
        | `XML -> Array.map (fun p -> p.Normal.nxml) disp.pl
    in
    let t = Types.Product.get ~kind disp.t in
    dispatch_prod0 disp t pl
  and dispatch_prod0 disp t pl =
    get_tests pl
      (fun (res,(p,q)) -> [p, (res,q)], [])
      (Types.Product.pi1 t)
      (dispatch_prod1 disp t)
      (fun x -> detect_left_tail_call (combine x))
  and dispatch_prod1 disp t t1 pl _ =
    get_tests pl
      (fun (ret1, ncatchv, (res,q)) -> [q, (ret1,res)], [] ) 
      (Types.Product.pi2_restricted t1 t)
      (dispatch_prod2 disp)
      (fun x -> detect_right_tail_call (combine x))
  and dispatch_prod2 disp t2 pl _ =
    let aux_final (ret2, ncatchv, (ret1, res)) =  
      IdMap.mapi_to_list (conv_source_prod ret1 ret2) res in
    return disp pl aux_final


  let rec dispatch_record disp : record option =
    let t = disp.t in
    if not (Types.Record.has_record t) then None 
    else
      match disp.label with
        | None -> 
            let (some,none) = Types.Record.empty_cases t in
            let some =
              if some then 
                let pl = Array.map (fun p -> match p.Normal.nrecord with
                                      | Normal.RecNolabel (Some x,_) -> [x]
                                      | Normal.RecNolabel (None,_) -> []
                                      | _ -> assert false) disp.pl in
                Some (return disp pl (IdMap.map_to_list conv_source_basic))
              else None
            in
            let none =
              if none then 
                let pl = Array.map (fun p -> match p.Normal.nrecord with
                                      | Normal.RecNolabel (_,Some x) -> [x]
                                      | Normal.RecNolabel (_,None) -> []
                                      | _ -> assert false) disp.pl in
                Some (return disp pl (IdMap.map_to_list conv_source_basic))
              else None
            in        
            Some (RecNolabel (some,none))
        | Some lab ->
            let t = Types.Record.split t lab in
            let pl = Array.map (fun p -> match p.Normal.nrecord with
                                  | Normal.RecLabel (_,l) -> l
                                  | _ -> assert false) disp.pl in
            Some (RecLabel (lab,dispatch_prod0 disp t pl))
(* soucis avec les ncatchv ?? *)

      
  let actions disp =
    match disp.actions with
      | Some a -> a
      | None ->
          let a = combine_kind
                    (dispatch_basic disp)
                    (dispatch_prod disp)
                    (dispatch_prod ~kind:`XML disp)
                    (dispatch_record disp)
          in
          disp.actions <- Some a;
          a

  let to_print = ref []

  module DSET = Set.Make (struct type t = int let compare (x:t) (y:t) = x - y end)
  let printed = ref DSET.empty

  let queue d =
    if not d.printed then (
      d.printed <- true;
      to_print := d :: !to_print
    )

  let rec print_source ppf = function
    | Catch  -> Format.fprintf ppf "v"
    | Const c -> Types.Print.print_const ppf c
    | Left (-1) -> Format.fprintf ppf "v1"
    | Right (-1) -> Format.fprintf ppf "v2"
    | Left i -> Format.fprintf ppf "l%i" i
    | Right j -> Format.fprintf ppf "r%i" j
    | Recompose (i,j) -> 
        Format.fprintf ppf "(%a,%a)" 
          print_source (Left i)
          print_source (Right j)

  let print_result ppf =
    Array.iteri 
      (fun i s ->
         if i > 0 then Format.fprintf ppf ",";
         print_source ppf s; 
      )

  let print_ret ppf (code,ret) = 
    Format.fprintf ppf "$%i" code;
    if Array.length ret <> 0 then 
      Format.fprintf ppf "(%a)" print_result ret

  let print_ret_opt ppf = function
    | None -> Format.fprintf ppf "*"
    | Some r -> print_ret ppf r

  let print_kind ppf actions =
    let print_lhs ppf (code,prefix,d) =
      let arity = match d.codes.(code) with (_,a,_) -> a in
      Format.fprintf ppf "$%i(" code;
      for i = 0 to arity - 1 do
        if i > 0 then Format.fprintf ppf ",";
        Format.fprintf ppf "%s%i" prefix i;
      done;
      Format.fprintf ppf ")" in
    let print_basic (t,ret) =
      Format.fprintf ppf " | %a -> %a@\n"
        Types.Print.print_descr t
        print_ret ret
    in
    let print_prod2 = function
      | Impossible -> assert false
      | Ignore r ->
          Format.fprintf ppf "        %a\n" 
            print_ret r
      | TailCall d ->
          queue d;
          Format.fprintf ppf "        disp_%i v2@\n" d.id
      | Dispatch (d, branches) ->
          queue d;
          Format.fprintf ppf "        match v2 with disp_%i@\n" d.id;
          Array.iteri 
            (fun code r ->
               Format.fprintf ppf "        | %a -> %a\n" 
                 print_lhs (code, "r", d)
                 print_ret r;
            )
            branches
    in
    let print_prod prefix ppf = function
      | Impossible -> ()
      | Ignore d2 ->
          Format.fprintf ppf " | %s(v1,v2) -> @\n" prefix;
          print_prod2 d2
      | TailCall d ->
          queue d;
          Format.fprintf ppf " | %s(v1,v2) -> @\n" prefix;
          Format.fprintf ppf "      disp_%i v1@\n" d.id
      | Dispatch (d,branches) ->
          queue d;
          Format.fprintf ppf " | %s(v1,v2) -> @\n" prefix;
          Format.fprintf ppf "      match v1 with disp_%i@\n" d.id;
          Array.iteri 
            (fun code d2 ->
               Format.fprintf ppf "      | %a -> @\n"
               print_lhs (code, "l", d);
               print_prod2 d2;
            )
            branches
    in
    let rec print_record_opt ppf = function
      | None -> ()
      | Some r -> 
          Format.fprintf ppf " | Record -> @\n";
          Format.fprintf ppf "     @[%a@]@\n"  print_record r
    and print_record ppf = function
      | RecNolabel (r1,r2) ->
          Format.fprintf ppf "SomeField:%a;NoField:%a" 
          print_ret_opt r1 print_ret_opt r2
      | RecLabel (l, d) ->
          let l = LabelPool.value l in
          Format.fprintf ppf "check label %s:@\n" l;
          Format.fprintf ppf "Present => @[%a@]@\n" (print_prod "record") d
    in
    
    List.iter print_basic actions.basic;
    print_prod "" ppf actions.prod;
    print_prod "XML" ppf actions.xml;
    print_record_opt ppf actions.record

  let print_actions ppf = function
    | AKind k -> print_kind ppf k
    | AIgnore r -> Format.fprintf ppf "v -> %a@\n" print_ret r

  let print_dispatcher ppf d =
(*    Format.fprintf ppf "Dispatcher %i accepts [%a]@\n" 
      d.id Types.Print.print_descr (Types.normalize d.t); 
    let print_code code (t, arity, m) =
      Format.fprintf ppf "  Returns $%i(arity=%i) for [%a]" 
        code arity
        Types.Print.print_descr (Types.normalize t);
(*      
      List.iter
        (fun (i,b) ->
           Format.fprintf ppf "[%i:" i;
           List.iter 
             (fun (v,i) ->  Format.fprintf ppf "%s=>%i;" v i)
             b;
           Format.fprintf ppf "]"
        ) m;  *)
      
      Format.fprintf ppf "@\n";
    in
    Array.iteri print_code d.codes;   *)
    Format.fprintf ppf "let disp_%i = function@\n" d.id;
    print_actions ppf (actions d);
    Format.fprintf ppf "====================================@\n"


  let rec print_dispatchers ppf =
    match !to_print with
      | [] -> ()
      | d :: rem -> 
          to_print := rem; 
          print_dispatcher ppf d; 
          print_dispatchers ppf


  let show ppf t pl lab =
    let disp = dispatcher t pl lab in
    queue disp;
    print_dispatchers ppf

  let debug_compile ppf t pl =
    let t = Types.descr t in
    let lab =
      List.fold_left
        (fun l p -> min l (Normal.first_label (descr p)))
        (Types.Record.first_label t) pl in
    let lab = if lab= LabelPool.dummy_max then None else Some lab in
    
    let pl = Array.of_list 
               (List.map (fun p -> Normal.normal lab Types.Record.any_or_absent [p]) pl) in

    show ppf t pl lab;
    Format.fprintf ppf "# compiled dispatchers: %i@\n" !cur_id
end

