viewcvs.cgi/typing/typer.ml

(* I. Transform the abstract syntax of types and patterns into
      the internal form *)

open Location
open Ast

exception Pattern of string
exception NonExhaustive of Types.descr
exception MultipleLabel of Types.label
exception Constraint of Types.descr * Types.descr * string
exception ShouldHave of Types.descr * string
exception WrongLabel of Types.descr * Types.label
exception UnboundId of string

let raise_loc loc exn = raise (Location (loc,exn))

(* Internal representation as a graph (desugar recursive types and regexp),
   to compute freevars, etc... *)

type ti = {
  id : int; 
  mutable loc' : loc;
  mutable fv : string SortedList.t option; 
  mutable descr': descr;
  mutable type_node: Types.node option;
  mutable pat_node: Patterns.node option
} 
and descr =
   [ `Alias of string * ti
   | `Type of Types.descr
   | `Or of ti * ti
   | `And of ti * ti
   | `Diff of ti * ti
   | `Times of ti * ti
   | `Arrow of ti * ti
   | `Record of Types.label * bool * ti
   | `Capture of Patterns.capture
   | `Constant of Patterns.capture * Types.const
   ]
    

module S = struct type t = string let compare = compare end
module StringMap = Map.Make(S)
module StringSet = Set.Make(S)

let mk' =
  let counter = ref 0 in
  fun loc ->
    incr counter;
    let rec x = { 
      id = !counter; 
      loc' = loc; 
      fv = None; 
      descr' = `Alias ("__dummy__", x);  
      type_node = None; 
      pat_node = None 
    } in
    x

let cons loc d =
  let x = mk' loc in
  x.descr' <- d;
  x
    
(* Note:
   Compilation of Regexp is implemented as a ``rewriting'' of
   the parsed syntax, in order to be able to print its result
   (for debugging for instance)
   
   It would be possible (and a little more efficient) to produce
   directly ti nodes.
*)
    
module Regexp = struct
  let memo = Hashtbl.create 51
  let defs = ref []
  let name =
    let c = ref 0 in
    fun () ->
      incr c;
      "#" ^ (string_of_int !c)

  let rec seq_vars accu = function
    | Epsilon | Elem _ -> accu
    | Seq (r1,r2) | Alt (r1,r2) -> seq_vars (seq_vars accu r1) r2
    | Star r | WeakStar r -> seq_vars accu r
    | SeqCapture (v,r) -> seq_vars (StringSet.add v accu) r

  let rec propagate vars = function
    | Epsilon -> `Epsilon
    | Elem x -> `Elem (vars,x)
    | Seq (r1,r2) -> `Seq (propagate vars r1,propagate vars r2)
    | Alt (r1,r2) -> `Alt (propagate vars r1, propagate vars r2)
    | Star r -> `Star (propagate vars r)
    | WeakStar r -> `WeakStar (propagate vars r)
    | SeqCapture (v,x) -> propagate (StringSet.add v vars) x

  let cup r1 r2 = 
    match (r1,r2) with
      | (_, `Empty) -> r1
      | (`Empty, _) -> r2
      | (`Res t1, `Res t2) -> `Res (mk noloc (Or (t1,t2)))

  let rec compile fin e seq : [`Res of Ast.ppat | `Empty] = 
    if List.mem seq e then `Empty
    else 
      let e = seq :: e in
      match seq with
        | [] ->
            `Res fin
        | `Epsilon :: rest -> 
            compile fin e rest
        | `Elem (vars,x) :: rest -> 
            let capt = StringSet.fold
                         (fun v t -> mk noloc (And (t, (mk noloc (Capture v)))))
                         vars x in
            `Res (mk noloc (Prod (capt, guard_compile fin rest)))
        | `Seq (r1,r2) :: rest -> 
            compile fin e (r1 :: r2 :: rest)
        | `Alt (r1,r2) :: rest -> 
            cup (compile fin e (r1::rest)) (compile fin e (r2::rest))
        | `Star r :: rest -> cup (compile fin e (r::seq)) (compile fin e rest) 
        | `WeakStar r :: rest -> cup (compile fin e rest) (compile fin e (r::seq))

  and guard_compile fin seq =
    try Hashtbl.find memo seq 
    with
        Not_found ->
          let n = name () in
          let v = mk noloc (PatVar n) in
          Hashtbl.add memo seq v;
          let d = compile fin [] seq in
          (match d with
             | `Empty -> assert false
             | `Res d -> defs := (n,d) :: !defs);
          v


  let atom_nil = Types.mk_atom "nil"
  let constant_nil v t = 
    mk noloc (And (t, (mk noloc (Constant (v, Types.Atom atom_nil)))))

  let compile regexp queue : ppat =
    let vars = seq_vars StringSet.empty regexp in
    let fin = StringSet.fold constant_nil vars queue in
    let n = guard_compile fin [propagate StringSet.empty regexp] in
    Hashtbl.clear memo;
    let d = !defs in
    defs := [];
    mk noloc (Recurs (n,d))
end

let compile_regexp = Regexp.compile


let rec compile env { loc = loc; descr = d } : ti = 
  match (d : Ast.ppat') with
  | PatVar s -> 
      (try StringMap.find s env
       with Not_found -> 
         raise_loc loc (Pattern ("Undefined type variable " ^ s))
      )
  | Recurs (t, b) -> compile (compile_many env b) t
  | Regexp (r,q) -> compile env (Regexp.compile r q)
  | Internal t -> cons loc (`Type t)
  | Or (t1,t2) -> cons loc (`Or (compile env t1, compile env t2))
  | And (t1,t2) -> cons loc (`And (compile env t1, compile env t2))
  | Diff (t1,t2) -> cons loc (`Diff (compile env t1, compile env t2))
  | Prod (t1,t2) -> cons loc (`Times (compile env t1, compile env t2))
  | Arrow (t1,t2) -> cons loc (`Arrow (compile env t1, compile env t2))
  | Record (l,o,t) -> cons loc (`Record (l,o,compile env t))
  | Constant (x,v) -> cons loc (`Constant (x,v))
  | Capture x -> cons loc (`Capture x)

and compile_many env b = 
  let b = List.map (fun (v,t) -> (v,t,mk' t.loc)) b in
  let env = 
    List.fold_left (fun env (v,t,x) -> StringMap.add v x env) env b in
  List.iter (fun (v,t,x) -> x.descr' <- `Alias (v, compile env t)) b;
  env


let rec comp_fv seen s =
  match s.fv with
    | Some l -> l
    | None ->
        let l = 
          match s.descr' with
            | `Alias (_,x) -> if List.memq s seen then [] else comp_fv (s :: seen) x
            | `Or (s1,s2) 
            | `And (s1,s2)
            | `Diff (s1,s2)
            | `Times (s1,s2)
            | `Arrow (s1,s2) -> SortedList.cup (comp_fv seen s1) (comp_fv seen s2)
            | `Record (l,opt,s) -> comp_fv seen s
            | `Type _ -> []
            | `Capture x
            | `Constant (x,_) -> [x]
        in
        if seen = [] then s.fv <- Some l;
        l


let fv = comp_fv []

let rec typ seen s : Types.descr =
  match s.descr' with
    | `Alias (v,x) ->
        if List.memq s seen then 
          raise_loc s.loc' 
            (Pattern 
               ("Unguarded recursion on variable " ^ v ^ " in this type"))
        else typ (s :: seen) x
    | `Type t -> t
    | `Or (s1,s2) -> Types.cup (typ seen s1) (typ seen s2)
    | `And (s1,s2) ->  Types.cap (typ seen s1) (typ seen s2)
    | `Diff (s1,s2) -> Types.diff (typ seen s1) (typ seen s2)
    | `Times (s1,s2) -> Types.times (typ_node s1) (typ_node s2)
    | `Arrow (s1,s2) -> Types.arrow (typ_node s1) (typ_node s2)
    | `Record (l,o,s) -> Types.record l o (typ_node s)
    | `Capture _ | `Constant _ -> assert false

and typ_node s : Types.node =
  match s.type_node with
    | Some x -> x
    | None ->
        let x = Types.make () in
        s.type_node <- Some x;
        let t = typ [] s in
        Types.define x t;
        x

let type_node s = Types.internalize (typ_node s)

let rec pat seen s : Patterns.descr =
  if fv s = [] then Patterns.constr (type_node s) else
  match s.descr' with
    | `Alias (v,x) ->
        if List.memq s seen then 
          raise_loc s.loc' 
            (Pattern 
               ("Unguarded recursion on variable " ^ v ^ " in this pattern"))
        else pat (s :: seen) x
    | `Or (s1,s2) -> Patterns.cup (pat seen s1) (pat seen s2)
    | `And (s1,s2) -> Patterns.cap (pat seen s1) (pat seen s2)
    | `Diff (s1,s2) when fv s2 = [] ->
        let s2 = Types.cons (Types.neg (Types.descr (type_node s2)))in
        Patterns.cap (pat seen s1) (Patterns.constr s2)
    | `Diff _ ->
        raise_loc s.loc' (Pattern "Difference not allowed in patterns")
    | `Times (s1,s2) -> Patterns.times (pat_node s1) (pat_node s2)
    | `Record (l,false,s) -> Patterns.record l (pat_node s)
    | `Record _ ->
        raise_loc s.loc' 
          (Pattern "Optional field not allowed in record patterns")
    | `Capture x ->  Patterns.capture x
    | `Constant (x,c) -> Patterns.constant x c
    | `Arrow _ ->
        raise_loc s.loc' (Pattern "Arrow not allowed in patterns")
    | `Type _ -> assert false

and pat_node s : Patterns.node =
  match s.pat_node with
    | Some x -> x
    | None ->
        let x = Patterns.make (fv s) in
        s.pat_node <- Some x;
        let t = pat [] s in
        Patterns.define x t;
        x

let global_types = ref StringMap.empty

let mk_typ e =
  if fv e = [] then type_node e 
  else raise_loc e.loc' (Pattern "Capture variables are not allowed in types")
    

let typ e =
  mk_typ (compile !global_types e)

let pat e =
  let e = compile !global_types e in
  pat_node e

let register_global_types b =
  let env = compile_many !global_types b in
  List.iter (fun (v,_) -> 
               let d = Types.descr (mk_typ (StringMap.find v env)) in
               let d = Types.normalize d in
               Types.Print.register_global v d
            ) b;
  global_types := env


(* II. Build skeleton *)

module Fv = StringSet

let rec expr { loc = loc; descr = d } = 
  let (fv,td) = 
    match d with
      | DebugTyper t -> (Fv.empty, Typed.DebugTyper (typ t))
      | Var s -> (Fv.singleton s, Typed.Var s)
      | Apply (e1,e2) -> 
          let (fv1,e1) = expr e1 and (fv2,e2) = expr e2 in
          (Fv.union fv1 fv2, Typed.Apply (e1,e2))
      | Abstraction a ->
          let iface = List.map (fun (t1,t2) -> (typ t1, typ t2)) a.fun_iface in
          let t = List.fold_left 
                    (fun accu (t1,t2) -> Types.cap accu (Types.arrow t1 t2)) 
                    Types.any iface in
          let iface = List.map 
                        (fun (t1,t2) -> (Types.descr t1, Types.descr t2)) 
                        iface in
          let (fv0,body) = branches a.fun_body in
          let fv = match a.fun_name with
            | None -> fv0
            | Some f -> Fv.remove f fv0 in
          (fv,
           Typed.Abstraction 
             { Typed.fun_name = a.fun_name;
               Typed.fun_iface = iface;
               Typed.fun_body = body;
               Typed.fun_typ = t;
               Typed.fun_fv = Fv.elements fv0
             }
          )
      | Cst c -> (Fv.empty, Typed.Cst c)
      | Pair (e1,e2) ->
          let (fv1,e1) = expr e1 and (fv2,e2) = expr e2 in
          (Fv.union fv1 fv2, Typed.Pair (e1,e2))
      | Dot (e,l) ->
          let (fv,e) = expr e in
          (fv,  Typed.Dot (e,l))
      | RecordLitt r -> 
          (* Note: quadratic check for non duplication of labels.
             Should improve that to O(n log n) for dealing
             with huge number of attributes ?
          *)
          let fv = ref Fv.empty in
          let labs = ref [] in
          let r = List.map 
                    (fun (l,e) -> 
                       let (fv2,e) = expr e in
                       if (List.mem l !labs) then 
                         raise_loc loc (MultipleLabel l);
                       labs := l :: !labs;
                       fv := Fv.union !fv fv2;
                       (l,e)
                    ) r in
          (!fv, Typed.RecordLitt r)
      | Op (op,le) ->
          let (fvs,ltes) = List.split (List.map expr le) in
          let fv = List.fold_left Fv.union Fv.empty fvs in
          (fv, Typed.Op (op,ltes))
      | Match (e,b) -> 
          let (fv1,e) = expr e
          and (fv2,b) = branches b in
          (Fv.union fv1 fv2, Typed.Match (e, b))
      | Map (e,b) ->
          let (fv1,e) = expr e
          and (fv2,b) = branches b in
          (Fv.union fv1 fv2, Typed.Map (e, b))
  in
  fv,
  { Typed.exp_loc = loc;
    Typed.exp_typ = Types.empty;
    Typed.exp_descr = td;
  }
              
  and branches b = 
    let fv = ref Fv.empty in
    let accept = ref Types.empty in
    let b = List.map 
              (fun (p,e) ->
                 let (fv2,e) = expr e in
                 fv := Fv.union !fv fv2;
                 let p = pat p in
                 accept := Types.cup !accept (Types.descr (Patterns.accept p));
                 { Typed.br_used = false;
                   Typed.br_pat = p;
                   Typed.br_body = e }
              ) b in
    (!fv, 
     { 
       Typed.br_typ = Types.empty; 
       Typed.br_branches = b; 
       Typed.br_accept = !accept 
     } 
    )

module Env = StringMap

open Typed


let check loc t s msg =
  if not (Types.subtype t s) then raise_loc loc (Constraint (t, s, msg))

let rec type_check env e constr precise = 
(*  Format.fprintf Format.std_formatter "constr=%a precise=%b@\n"
    Types.Print.print_descr constr precise; 
*)
  let d = type_check' e.exp_loc env e.exp_descr constr precise in
  e.exp_typ <- Types.cup e.exp_typ d;
  d

and type_check' loc env e constr precise = match e with
  | Abstraction a ->
      let t =
        try Types.Arrow.check_strenghten a.fun_typ constr 
        with Not_found -> 
          raise_loc loc 
          (ShouldHave
             (constr, "but the interface of the abstraction is not compatible"))
      in
      let env = match a.fun_name with
        | None -> env
        | Some f -> Env.add f a.fun_typ env in
      List.iter 
        (fun (t1,t2) ->
           ignore (type_check_branches loc env t1 a.fun_body t2 false)
        ) a.fun_iface;
      t
  | Match (e,b) ->
      let t = type_check env e b.br_accept true in
      type_check_branches loc env t b constr precise

  | Pair (e1,e2) -> 
      let rects = Types.Product.get constr in
      if Types.Product.is_empty rects then 
        raise_loc loc (ShouldHave (constr,"but it is a pair."));
      let pi1 = Types.Product.pi1 rects in

      let t1 = type_check env e1 (Types.Product.pi1 rects) 
                 (precise || (Types.Product.need_second rects))in
      let rects = Types.Product.restrict_1 rects t1 in
      let t2 = type_check env e2 (Types.Product.pi2 rects) precise in
      if precise then 
        Types.times (Types.cons t1) (Types.cons t2)
      else
        constr

  | RecordLitt r ->
      let rconstr = Types.Record.get constr in
      if Types.Record.is_empty rconstr then
        raise_loc loc (ShouldHave (constr,"but it is a record."));

      let (rconstr,res) = 
        List.fold_left 
          (fun (rconstr,res) (l,e) ->
             let rconstr = Types.Record.restrict_label_present rconstr l in
             let pi = Types.Record.project_field rconstr l in
             if Types.Record.is_empty rconstr then
               raise_loc loc 
                 (ShouldHave (constr,(Printf.sprintf 
                                        "Field %s is not allowed here."
                                        (Types.label_name l)
                                     )
                             ));
             let t = type_check env e pi true in
             let rconstr = Types.Record.restrict_field rconstr l t in
             
             let res = 
               if precise 
               then Types.cap res (Types.record l false (Types.cons t))
               else res in
             (rconstr,res)
          ) (rconstr, if precise then Types.Record.any else constr) r
      in
      res

  | Map (e,b) ->
      let t = type_check env e (Sequence.star b.br_accept) true in

      let constr' = Sequence.approx (Types.cap Sequence.any constr) in
      let exact = Types.subtype (Sequence.star constr') constr in

      if exact then (
        (* Note: typing mail fail because of the approx on t *)
        let res = type_check_branches loc env (Sequence.approx t) 
                    b constr' precise in
        if precise then Sequence.star res else constr
      )
      else
        (* Note: 
           - could be more precise by integrating the decomposition
           of constr inside Sequence.map.
        *)
        let res = 
          Sequence.map 
            (fun t -> type_check_branches loc env t b constr' true) 
            t in
        if not exact then check loc res constr "";
        if precise then res else constr
  | Op ("@", [e1;e2]) ->
      let constr' = Sequence.star 
                      (Sequence.approx (Types.cap Sequence.any constr)) in
      let exact = Types.subtype constr' constr in
      if exact then
        let t1 = type_check env e1 constr' precise
        and t2 = type_check env e2 constr' precise in
        if precise then Sequence.concat t1 t2 else constr
      else
        (* Note:
           the knownledge of t1 may makes it useless to
           check t2 with 'precise' ... *)
        let t1 = type_check env e1 constr' true
        and t2 = type_check env e2 constr' true in
        let res = Sequence.concat t1 t2 in
        check loc res constr "";
        if precise then res else constr
  | Op ("flatten", [e]) ->
      let constr' = Sequence.star 
                      (Sequence.approx (Types.cap Sequence.any constr)) in
      let sconstr' = Sequence.star constr' in
      let exact = Types.subtype constr' constr in
      if exact then
        let t = type_check env e sconstr' precise in
        if precise then Sequence.flatten t else constr
      else
        let t = type_check env e sconstr' true in
        let res = Sequence.flatten t in
        check loc res constr "";
        if precise then res else constr
  | _ -> 
      let t : Types.descr = compute_type' loc env e in
      check loc t constr "";
      t

and compute_type env e =
  type_check env e Types.any true

and compute_type' loc env = function
  | DebugTyper t -> Types.descr t
  | Var s -> 
      (try Env.find s env 
       with Not_found -> raise_loc loc (UnboundId s)
      )
  | Apply (e1,e2) ->
      let t1 = type_check env e1 Types.Arrow.any true in
      let t1 = Types.Arrow.get t1 in
      let dom = Types.Arrow.domain t1 in
      if Types.Arrow.need_arg t1 then
        let t2 = type_check env e2 dom true in
        Types.Arrow.apply t1 t2
      else
        (ignore (type_check env e2 dom false); Types.Arrow.apply_noarg t1)
  | Cst c -> Types.constant c
  | Dot (e,l) ->
      let t = type_check env e Types.Record.any true in
         (try (Types.Record.project t l) 
          with Not_found -> raise_loc loc (WrongLabel(t,l)))
  | Op (op, el) ->
      let args = List.map (fun e -> (e.exp_loc, compute_type env e)) el in
      type_op loc op args
  | Map (e,b) ->
      let t = compute_type env e in
      Sequence.map (fun t -> type_check_branches loc env t b Types.any true) t

(* We keep these cases here to allow comparison and benchmarking ...
   Just comment the corresponding cases in type_check' to
   activate these ones.
*)
  | Pair (e1,e2) -> 
      let t1 = compute_type env e1 
      and t2 = compute_type env e2 in
      Types.times (Types.cons t1) (Types.cons t2)
  | RecordLitt r ->
      List.fold_left 
        (fun accu (l,e) ->
           let t = compute_type env e in
           let t = Types.record l false (Types.cons t) in
           Types.cap accu t
        ) Types.Record.any r


  | _ -> assert false

and type_check_branches loc env targ brs constr precise =
  if Types.is_empty targ then Types.empty 
  else (
    brs.br_typ <- Types.cup brs.br_typ targ;
    branches_aux loc env targ 
      (if precise then Types.empty else constr) 
      constr precise brs.br_branches
  )
    
and branches_aux loc env targ tres constr precise = function
  | [] -> raise_loc loc (NonExhaustive targ)
  | b :: rem ->
      let p = b.br_pat in
      let acc = Types.descr (Patterns.accept p) in

      let targ' = Types.cap targ acc in
      if Types.is_empty targ' 
      then branches_aux loc env targ tres constr precise rem
      else 
        ( b.br_used <- true;
          let res = Patterns.filter targ' p in
          let env' = List.fold_left 
                       (fun env (x,t) -> Env.add x (Types.descr t) env) 
                       env res in
          let t = type_check env' b.br_body constr precise in
          let tres = if precise then Types.cup t tres else tres in
          let targ'' = Types.diff targ acc in
          if (Types.non_empty targ'') then 
            branches_aux loc env targ'' tres constr precise rem 
          else
            tres
        )

and type_op loc op args =
  match (op,args) with
    | ("+", [loc1,t1; loc2,t2]) ->
        type_int_binop Intervals.add loc1 t1 loc2 t2
    | ("*", [loc1,t1; loc2,t2]) ->
        type_int_binop (fun i1 i2 -> Intervals.any) loc1 t1 loc2 t2
    | ("@", [loc1,t1; loc2,t2]) ->
        check loc1 t1 Sequence.any
          "The first argument of @ must be a sequence";
        Sequence.concat t1 t2
    | ("flatten", [loc1,t1]) ->
        check loc1 t1 Sequence.seqseq 
          "The argument of flatten must be a sequence of sequences";
        Sequence.flatten t1
    | _ -> assert false

and type_int_binop f loc1 t1 loc2 t2 =
  if not (Types.Int.is_int t1) then
    raise_loc loc1 
      (Constraint 
         (t1,Types.Int.any,
          "The first argument must be an integer"));
  if not (Types.Int.is_int t2) then
    raise_loc loc2
      (Constraint 
               (t2,Types.Int.any,
                "The second argument must be an integer"));
  Types.Int.put
    (f (Types.Int.get t1) (Types.Int.get t2));
  

1	(* I. Transform the abstract syntax of types and patterns into
2	the internal form *)
3
4	open Location
5	open Ast
6
7	exception Pattern of string
8	exception NonExhaustive of Types.descr
9	exception MultipleLabel of Types.label
10	exception Constraint of Types.descr * Types.descr * string
11	exception ShouldHave of Types.descr * string
12	exception WrongLabel of Types.descr * Types.label
13	exception UnboundId of string
14
15	let raise_loc loc exn = raise (Location (loc,exn))
16
17	(* Internal representation as a graph (desugar recursive types and regexp),
18	to compute freevars, etc... *)
19
20	type ti = {
21	id : int;
22	mutable loc' : loc;
23	mutable fv : string SortedList.t option;
24	mutable descr': descr;
25	mutable type_node: Types.node option;
26	mutable pat_node: Patterns.node option
27	}
28	and descr =
29	[ `Alias of string * ti
30	\| `Type of Types.descr
31	\| `Or of ti * ti
32	\| `And of ti * ti
33	\| `Diff of ti * ti
34	\| `Times of ti * ti
35	\| `Arrow of ti * ti
36	\| `Record of Types.label * bool * ti
37	\| `Capture of Patterns.capture
38	\| `Constant of Patterns.capture * Types.const
39	]
40
41
42
43	module S = struct type t = string let compare = compare end
44	module StringMap = Map.Make(S)
45	module StringSet = Set.Make(S)
46
47	let mk' =
48	let counter = ref 0 in
49	fun loc ->
50	incr counter;
51	let rec x = {
52	id = !counter;
53	loc' = loc;
54	fv = None;
55	descr' = `Alias ("__dummy__", x);
56	type_node = None;
57	pat_node = None
58	} in
59	x
60
61	let cons loc d =
62	let x = mk' loc in
63	x.descr' <- d;
64	x
65
66	(* Note:
67	Compilation of Regexp is implemented as a ``rewriting'' of
68	the parsed syntax, in order to be able to print its result
69	(for debugging for instance)
70
71	It would be possible (and a little more efficient) to produce
72	directly ti nodes.
73	*)
74
75	module Regexp = struct
76	let memo = Hashtbl.create 51
77	let defs = ref []
78	let name =
79	let c = ref 0 in
80	fun () ->
81	incr c;
82	"#" ^ (string_of_int !c)
83
84	let rec seq_vars accu = function
85	\| Epsilon \| Elem _ -> accu
86	\| Seq (r1,r2) \| Alt (r1,r2) -> seq_vars (seq_vars accu r1) r2
87	\| Star r \| WeakStar r -> seq_vars accu r
88	\| SeqCapture (v,r) -> seq_vars (StringSet.add v accu) r
89
90	let rec propagate vars = function
91	\| Epsilon -> `Epsilon
92	\| Elem x -> `Elem (vars,x)
93	\| Seq (r1,r2) -> `Seq (propagate vars r1,propagate vars r2)
94	\| Alt (r1,r2) -> `Alt (propagate vars r1, propagate vars r2)
95	\| Star r -> `Star (propagate vars r)
96	\| WeakStar r -> `WeakStar (propagate vars r)
97	\| SeqCapture (v,x) -> propagate (StringSet.add v vars) x
98
99	let cup r1 r2 =
100	match (r1,r2) with
101	\| (_, `Empty) -> r1
102	\| (`Empty, _) -> r2
103	\| (`Res t1, `Res t2) -> `Res (mk noloc (Or (t1,t2)))
104
105	let rec compile fin e seq : [`Res of Ast.ppat \| `Empty] =
106	if List.mem seq e then `Empty
107	else
108	let e = seq :: e in
109	match seq with
110	\| [] ->
111	`Res fin
112	\| `Epsilon :: rest ->
113	compile fin e rest
114	\| `Elem (vars,x) :: rest ->
115	let capt = StringSet.fold
116	(fun v t -> mk noloc (And (t, (mk noloc (Capture v)))))
117	vars x in
118	`Res (mk noloc (Prod (capt, guard_compile fin rest)))
119	\| `Seq (r1,r2) :: rest ->
120	compile fin e (r1 :: r2 :: rest)
121	\| `Alt (r1,r2) :: rest ->
122	cup (compile fin e (r1::rest)) (compile fin e (r2::rest))
123	\| `Star r :: rest -> cup (compile fin e (r::seq)) (compile fin e rest)
124	\| `WeakStar r :: rest -> cup (compile fin e rest) (compile fin e (r::seq))
125
126	and guard_compile fin seq =
127	try Hashtbl.find memo seq
128	with
129	Not_found ->
130	let n = name () in
131	let v = mk noloc (PatVar n) in
132	Hashtbl.add memo seq v;
133	let d = compile fin [] seq in
134	(match d with
135	\| `Empty -> assert false
136	\| `Res d -> defs := (n,d) :: !defs);
137	v
138
139
140	let atom_nil = Types.mk_atom "nil"
141	let constant_nil v t =
142	mk noloc (And (t, (mk noloc (Constant (v, Types.Atom atom_nil)))))
143
144	let compile regexp queue : ppat =
145	let vars = seq_vars StringSet.empty regexp in
146	let fin = StringSet.fold constant_nil vars queue in
147	let n = guard_compile fin [propagate StringSet.empty regexp] in
148	Hashtbl.clear memo;
149	let d = !defs in
150	defs := [];
151	mk noloc (Recurs (n,d))
152	end
153
154	let compile_regexp = Regexp.compile
155
156
157	let rec compile env { loc = loc; descr = d } : ti =
158	match (d : Ast.ppat') with
159	\| PatVar s ->
160	(try StringMap.find s env
161	with Not_found ->
162	raise_loc loc (Pattern ("Undefined type variable " ^ s))
163	)
164	\| Recurs (t, b) -> compile (compile_many env b) t
165	\| Regexp (r,q) -> compile env (Regexp.compile r q)
166	\| Internal t -> cons loc (`Type t)
167	\| Or (t1,t2) -> cons loc (`Or (compile env t1, compile env t2))
168	\| And (t1,t2) -> cons loc (`And (compile env t1, compile env t2))
169	\| Diff (t1,t2) -> cons loc (`Diff (compile env t1, compile env t2))
170	\| Prod (t1,t2) -> cons loc (`Times (compile env t1, compile env t2))
171	\| Arrow (t1,t2) -> cons loc (`Arrow (compile env t1, compile env t2))
172	\| Record (l,o,t) -> cons loc (`Record (l,o,compile env t))
173	\| Constant (x,v) -> cons loc (`Constant (x,v))
174	\| Capture x -> cons loc (`Capture x)
175
176	and compile_many env b =
177	let b = List.map (fun (v,t) -> (v,t,mk' t.loc)) b in
178	let env =
179	List.fold_left (fun env (v,t,x) -> StringMap.add v x env) env b in
180	List.iter (fun (v,t,x) -> x.descr' <- `Alias (v, compile env t)) b;
181	env
182
183
184	let rec comp_fv seen s =
185	match s.fv with
186	\| Some l -> l
187	\| None ->
188	let l =
189	match s.descr' with
190	\| `Alias (_,x) -> if List.memq s seen then [] else comp_fv (s :: seen) x
191	\| `Or (s1,s2)
192	\| `And (s1,s2)
193	\| `Diff (s1,s2)
194	\| `Times (s1,s2)
195	\| `Arrow (s1,s2) -> SortedList.cup (comp_fv seen s1) (comp_fv seen s2)
196	\| `Record (l,opt,s) -> comp_fv seen s
197	\| `Type _ -> []
198	\| `Capture x
199	\| `Constant (x,_) -> [x]
200	in
201	if seen = [] then s.fv <- Some l;
202	l
203
204
205	let fv = comp_fv []
206
207	let rec typ seen s : Types.descr =
208	match s.descr' with
209	\| `Alias (v,x) ->
210	if List.memq s seen then
211	raise_loc s.loc'
212	(Pattern
213	("Unguarded recursion on variable " ^ v ^ " in this type"))
214	else typ (s :: seen) x
215	\| `Type t -> t
216	\| `Or (s1,s2) -> Types.cup (typ seen s1) (typ seen s2)
217	\| `And (s1,s2) -> Types.cap (typ seen s1) (typ seen s2)
218	\| `Diff (s1,s2) -> Types.diff (typ seen s1) (typ seen s2)
219	\| `Times (s1,s2) -> Types.times (typ_node s1) (typ_node s2)
220	\| `Arrow (s1,s2) -> Types.arrow (typ_node s1) (typ_node s2)
221	\| `Record (l,o,s) -> Types.record l o (typ_node s)
222	\| `Capture _ \| `Constant _ -> assert false
223
224	and typ_node s : Types.node =
225	match s.type_node with
226	\| Some x -> x
227	\| None ->
228	let x = Types.make () in
229	s.type_node <- Some x;
230	let t = typ [] s in
231	Types.define x t;
232	x
233
234	let type_node s = Types.internalize (typ_node s)
235
236	let rec pat seen s : Patterns.descr =
237	if fv s = [] then Patterns.constr (type_node s) else
238	match s.descr' with
239	\| `Alias (v,x) ->
240	if List.memq s seen then
241	raise_loc s.loc'
242	(Pattern
243	("Unguarded recursion on variable " ^ v ^ " in this pattern"))
244	else pat (s :: seen) x
245	\| `Or (s1,s2) -> Patterns.cup (pat seen s1) (pat seen s2)
246	\| `And (s1,s2) -> Patterns.cap (pat seen s1) (pat seen s2)
247	\| `Diff (s1,s2) when fv s2 = [] ->
248	let s2 = Types.cons (Types.neg (Types.descr (type_node s2)))in
249	Patterns.cap (pat seen s1) (Patterns.constr s2)
250	\| `Diff _ ->
251	raise_loc s.loc' (Pattern "Difference not allowed in patterns")
252	\| `Times (s1,s2) -> Patterns.times (pat_node s1) (pat_node s2)
253	\| `Record (l,false,s) -> Patterns.record l (pat_node s)
254	\| `Record _ ->
255	raise_loc s.loc'
256	(Pattern "Optional field not allowed in record patterns")
257	\| `Capture x -> Patterns.capture x
258	\| `Constant (x,c) -> Patterns.constant x c
259	\| `Arrow _ ->
260	raise_loc s.loc' (Pattern "Arrow not allowed in patterns")
261	\| `Type _ -> assert false
262
263	and pat_node s : Patterns.node =
264	match s.pat_node with
265	\| Some x -> x
266	\| None ->
267	let x = Patterns.make (fv s) in
268	s.pat_node <- Some x;
269	let t = pat [] s in
270	Patterns.define x t;
271	x
272
273	let global_types = ref StringMap.empty
274
275	let mk_typ e =
276	if fv e = [] then type_node e
277	else raise_loc e.loc' (Pattern "Capture variables are not allowed in types")
278
279
280	let typ e =
281	mk_typ (compile !global_types e)
282
283	let pat e =
284	let e = compile !global_types e in
285	pat_node e
286
287	let register_global_types b =
288	let env = compile_many !global_types b in
289	List.iter (fun (v,_) ->
290	let d = Types.descr (mk_typ (StringMap.find v env)) in
291	let d = Types.normalize d in
292	Types.Print.register_global v d
293	) b;
294	global_types := env
295
296
297	(* II. Build skeleton *)
298
299	module Fv = StringSet
300
301	let rec expr { loc = loc; descr = d } =
302	let (fv,td) =
303	match d with
304	\| DebugTyper t -> (Fv.empty, Typed.DebugTyper (typ t))
305	\| Var s -> (Fv.singleton s, Typed.Var s)
306	\| Apply (e1,e2) ->
307	let (fv1,e1) = expr e1 and (fv2,e2) = expr e2 in
308	(Fv.union fv1 fv2, Typed.Apply (e1,e2))
309	\| Abstraction a ->
310	let iface = List.map (fun (t1,t2) -> (typ t1, typ t2)) a.fun_iface in
311	let t = List.fold_left
312	(fun accu (t1,t2) -> Types.cap accu (Types.arrow t1 t2))
313	Types.any iface in
314	let iface = List.map
315	(fun (t1,t2) -> (Types.descr t1, Types.descr t2))
316	iface in
317	let (fv0,body) = branches a.fun_body in
318	let fv = match a.fun_name with
319	\| None -> fv0
320	\| Some f -> Fv.remove f fv0 in
321	(fv,
322	Typed.Abstraction
323	{ Typed.fun_name = a.fun_name;
324	Typed.fun_iface = iface;
325	Typed.fun_body = body;
326	Typed.fun_typ = t;
327	Typed.fun_fv = Fv.elements fv0
328	}
329	)
330	\| Cst c -> (Fv.empty, Typed.Cst c)
331	\| Pair (e1,e2) ->
332	let (fv1,e1) = expr e1 and (fv2,e2) = expr e2 in
333	(Fv.union fv1 fv2, Typed.Pair (e1,e2))
334	\| Dot (e,l) ->
335	let (fv,e) = expr e in
336	(fv, Typed.Dot (e,l))
337	\| RecordLitt r ->
338	(* Note: quadratic check for non duplication of labels.
339	Should improve that to O(n log n) for dealing
340	with huge number of attributes ?
341	*)
342	let fv = ref Fv.empty in
343	let labs = ref [] in
344	let r = List.map
345	(fun (l,e) ->
346	let (fv2,e) = expr e in
347	if (List.mem l !labs) then
348	raise_loc loc (MultipleLabel l);
349	labs := l :: !labs;
350	fv := Fv.union !fv fv2;
351	(l,e)
352	) r in
353	(!fv, Typed.RecordLitt r)
354	\| Op (op,le) ->
355	let (fvs,ltes) = List.split (List.map expr le) in
356	let fv = List.fold_left Fv.union Fv.empty fvs in
357	(fv, Typed.Op (op,ltes))
358	\| Match (e,b) ->
359	let (fv1,e) = expr e
360	and (fv2,b) = branches b in
361	(Fv.union fv1 fv2, Typed.Match (e, b))
362	\| Map (e,b) ->
363	let (fv1,e) = expr e
364	and (fv2,b) = branches b in
365	(Fv.union fv1 fv2, Typed.Map (e, b))
366	in
367	fv,
368	{ Typed.exp_loc = loc;
369	Typed.exp_typ = Types.empty;
370	Typed.exp_descr = td;
371	}
372
373	and branches b =
374	let fv = ref Fv.empty in
375	let accept = ref Types.empty in
376	let b = List.map
377	(fun (p,e) ->
378	let (fv2,e) = expr e in
379	fv := Fv.union !fv fv2;
380	let p = pat p in
381	accept := Types.cup !accept (Types.descr (Patterns.accept p));
382	{ Typed.br_used = false;
383	Typed.br_pat = p;
384	Typed.br_body = e }
385	) b in
386	(!fv,
387	{
388	Typed.br_typ = Types.empty;
389	Typed.br_branches = b;
390	Typed.br_accept = !accept
391	}
392	)
393
394	module Env = StringMap
395
396	open Typed
397
398
399	let check loc t s msg =
400	if not (Types.subtype t s) then raise_loc loc (Constraint (t, s, msg))
401
402	let rec type_check env e constr precise =
403	(* Format.fprintf Format.std_formatter "constr=%a precise=%b@\n"
404	Types.Print.print_descr constr precise;
405	*)
406	let d = type_check' e.exp_loc env e.exp_descr constr precise in
407	e.exp_typ <- Types.cup e.exp_typ d;
408	d
409
410	and type_check' loc env e constr precise = match e with
411	\| Abstraction a ->
412	let t =
413	try Types.Arrow.check_strenghten a.fun_typ constr
414	with Not_found ->
415	raise_loc loc
416	(ShouldHave
417	(constr, "but the interface of the abstraction is not compatible"))
418	in
419	let env = match a.fun_name with
420	\| None -> env
421	\| Some f -> Env.add f a.fun_typ env in
422	List.iter
423	(fun (t1,t2) ->
424	ignore (type_check_branches loc env t1 a.fun_body t2 false)
425	) a.fun_iface;
426	t
427	\| Match (e,b) ->
428	let t = type_check env e b.br_accept true in
429	type_check_branches loc env t b constr precise
430
431	\| Pair (e1,e2) ->
432	let rects = Types.Product.get constr in
433	if Types.Product.is_empty rects then
434	raise_loc loc (ShouldHave (constr,"but it is a pair."));
435	let pi1 = Types.Product.pi1 rects in
436
437	let t1 = type_check env e1 (Types.Product.pi1 rects)
438	(precise \|\| (Types.Product.need_second rects))in
439	let rects = Types.Product.restrict_1 rects t1 in
440	let t2 = type_check env e2 (Types.Product.pi2 rects) precise in
441	if precise then
442	Types.times (Types.cons t1) (Types.cons t2)
443	else
444	constr
445
446	\| RecordLitt r ->
447	let rconstr = Types.Record.get constr in
448	if Types.Record.is_empty rconstr then
449	raise_loc loc (ShouldHave (constr,"but it is a record."));
450
451	let (rconstr,res) =
452	List.fold_left
453	(fun (rconstr,res) (l,e) ->
454	let rconstr = Types.Record.restrict_label_present rconstr l in
455	let pi = Types.Record.project_field rconstr l in
456	if Types.Record.is_empty rconstr then
457	raise_loc loc
458	(ShouldHave (constr,(Printf.sprintf
459	"Field %s is not allowed here."
460	(Types.label_name l)
461	)
462	));
463	let t = type_check env e pi true in
464	let rconstr = Types.Record.restrict_field rconstr l t in
465
466	let res =
467	if precise
468	then Types.cap res (Types.record l false (Types.cons t))
469	else res in
470	(rconstr,res)
471	) (rconstr, if precise then Types.Record.any else constr) r
472	in
473	res
474
475	\| Map (e,b) ->
476	let t = type_check env e (Sequence.star b.br_accept) true in
477
478	let constr' = Sequence.approx (Types.cap Sequence.any constr) in
479	let exact = Types.subtype (Sequence.star constr') constr in
480
481	if exact then (
482	(* Note: typing mail fail because of the approx on t *)
483	let res = type_check_branches loc env (Sequence.approx t)
484	b constr' precise in
485	if precise then Sequence.star res else constr
486	)
487	else
488	(* Note:
489	- could be more precise by integrating the decomposition
490	of constr inside Sequence.map.
491	*)
492	let res =
493	Sequence.map
494	(fun t -> type_check_branches loc env t b constr' true)
495	t in
496	if not exact then check loc res constr "";
497	if precise then res else constr
498	\| Op ("@", [e1;e2]) ->
499	let constr' = Sequence.star
500	(Sequence.approx (Types.cap Sequence.any constr)) in
501	let exact = Types.subtype constr' constr in
502	if exact then
503	let t1 = type_check env e1 constr' precise
504	and t2 = type_check env e2 constr' precise in
505	if precise then Sequence.concat t1 t2 else constr
506	else
507	(* Note:
508	the knownledge of t1 may makes it useless to
509	check t2 with 'precise' ... *)
510	let t1 = type_check env e1 constr' true
511	and t2 = type_check env e2 constr' true in
512	let res = Sequence.concat t1 t2 in
513	check loc res constr "";
514	if precise then res else constr
515	\| Op ("flatten", [e]) ->
516	let constr' = Sequence.star
517	(Sequence.approx (Types.cap Sequence.any constr)) in
518	let sconstr' = Sequence.star constr' in
519	let exact = Types.subtype constr' constr in
520	if exact then
521	let t = type_check env e sconstr' precise in
522	if precise then Sequence.flatten t else constr
523	else
524	let t = type_check env e sconstr' true in
525	let res = Sequence.flatten t in
526	check loc res constr "";
527	if precise then res else constr
528	\| _ ->
529	let t : Types.descr = compute_type' loc env e in
530	check loc t constr "";
531	t
532
533	and compute_type env e =
534	type_check env e Types.any true
535
536	and compute_type' loc env = function
537	\| DebugTyper t -> Types.descr t
538	\| Var s ->
539	(try Env.find s env
540	with Not_found -> raise_loc loc (UnboundId s)
541	)
542	\| Apply (e1,e2) ->
543	let t1 = type_check env e1 Types.Arrow.any true in
544	let t1 = Types.Arrow.get t1 in
545	let dom = Types.Arrow.domain t1 in
546	if Types.Arrow.need_arg t1 then
547	let t2 = type_check env e2 dom true in
548	Types.Arrow.apply t1 t2
549	else
550	(ignore (type_check env e2 dom false); Types.Arrow.apply_noarg t1)
551	\| Cst c -> Types.constant c
552	\| Dot (e,l) ->
553	let t = type_check env e Types.Record.any true in
554	(try (Types.Record.project t l)
555	with Not_found -> raise_loc loc (WrongLabel(t,l)))
556	\| Op (op, el) ->
557	let args = List.map (fun e -> (e.exp_loc, compute_type env e)) el in
558	type_op loc op args
559	\| Map (e,b) ->
560	let t = compute_type env e in
561	Sequence.map (fun t -> type_check_branches loc env t b Types.any true) t
562
563	(* We keep these cases here to allow comparison and benchmarking ...
564	Just comment the corresponding cases in type_check' to
565	activate these ones.
566	*)
567	\| Pair (e1,e2) ->
568	let t1 = compute_type env e1
569	and t2 = compute_type env e2 in
570	Types.times (Types.cons t1) (Types.cons t2)
571	\| RecordLitt r ->
572	List.fold_left
573	(fun accu (l,e) ->
574	let t = compute_type env e in
575	let t = Types.record l false (Types.cons t) in
576	Types.cap accu t
577	) Types.Record.any r
578
579
580	\| _ -> assert false
581
582	and type_check_branches loc env targ brs constr precise =
583	if Types.is_empty targ then Types.empty
584	else (
585	brs.br_typ <- Types.cup brs.br_typ targ;
586	branches_aux loc env targ
587	(if precise then Types.empty else constr)
588	constr precise brs.br_branches
589	)
590
591	and branches_aux loc env targ tres constr precise = function
592	\| [] -> raise_loc loc (NonExhaustive targ)
593	\| b :: rem ->
594	let p = b.br_pat in
595	let acc = Types.descr (Patterns.accept p) in
596
597	let targ' = Types.cap targ acc in
598	if Types.is_empty targ'
599	then branches_aux loc env targ tres constr precise rem
600	else
601	( b.br_used <- true;
602	let res = Patterns.filter targ' p in
603	let env' = List.fold_left
604	(fun env (x,t) -> Env.add x (Types.descr t) env)
605	env res in
606	let t = type_check env' b.br_body constr precise in
607	let tres = if precise then Types.cup t tres else tres in
608	let targ'' = Types.diff targ acc in
609	if (Types.non_empty targ'') then
610	branches_aux loc env targ'' tres constr precise rem
611	else
612	tres
613	)
614
615	and type_op loc op args =
616	match (op,args) with
617	\| ("+", [loc1,t1; loc2,t2]) ->
618	type_int_binop Intervals.add loc1 t1 loc2 t2
619	\| ("*", [loc1,t1; loc2,t2]) ->
620	type_int_binop (fun i1 i2 -> Intervals.any) loc1 t1 loc2 t2
621	\| ("@", [loc1,t1; loc2,t2]) ->
622	check loc1 t1 Sequence.any
623	"The first argument of @ must be a sequence";
624	Sequence.concat t1 t2
625	\| ("flatten", [loc1,t1]) ->
626	check loc1 t1 Sequence.seqseq
627	"The argument of flatten must be a sequence of sequences";
628	Sequence.flatten t1
629	\| _ -> assert false
630
631	and type_int_binop f loc1 t1 loc2 t2 =
632	if not (Types.Int.is_int t1) then
633	raise_loc loc1
634	(Constraint
635	(t1,Types.Int.any,
636	"The first argument must be an integer"));
637	if not (Types.Int.is_int t2) then
638	raise_loc loc2
639	(Constraint
640	(t2,Types.Int.any,
641	"The second argument must be an integer"));
642	Types.Int.put
643	(f (Types.Int.get t1) (Types.Int.get t2));
644
645